[omniORB] omniORB 4.0.2 / omniORBpy 2.2 soon

[Bastiaan Bakker]

OK, here's a patch to acinclude.m4 and mk/beforeauto.mk.in. It checks
for availability of pkg-config in your path and if it is and
omni_cv_openssl_root does not equal 'no' it will try to determine SSL
root, compile flags and libs using pkg-config. 
One 'odd' thing is that it if pkg-config is available it will override
any explicit --with-openssl= specification of the openssl dir. The main
reason for this behaviour is to enable the PRM build with
--with-openssl=/usr.
The patched OMNI_OPENSSL_ROOT macro uses the PKG_CHECK_MODULES macro of
the pkgconfig package. I've attached the m4 of RH9's version for
inclusion in aclocal.m4. 

Cheers,

Bastiaan Bakker

PS. Warning: I've tested this only on a RH9 machine, platforms without a
package config for OpenSSL or even pkg-config are untested.

 
On Fri, 2003-07-04 at 18:13, Duncan Grisby wrote:
> On Thursday 3 July, Bastiaan Bakker wrote:
> 
> [...]
> > Cause: incorrect OpenSSL compile flags. 
> > OpenSSL on RH9 includes Kerberos support and therefore needs some extra
> > compile and link options. Preferably these are determined through
> > pkg-config (and appriopate the M4 macro's):
> 
> [...]
> > Probably the nicest way to handle this is to have ./configure obtain
> > these values from pkg-config if available and fall back to the old
> > method otherwise...
> 
> I don't have a RH9 machine to try this with. Are you able to come up
> with some autoconf stuff to figure it out?  If so, that would be very
> helpful.
> 
> Cheers,
> 
> Duncan.
-------------- next part --------------
A non-text attachment was scrubbed...
Name: omniORB.rh9compile.diff
Type: text/x-patch
Size: 3109 bytes
Desc: not available
Url : http://www.omniorb-support.com/pipermail/omniorb-list/attachments/20030707/f0ca2c93/omniORB.rh9compile.bin
-------------- next part --------------

dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
dnl also defines GSTUFF_PKG_ERRORS on error
AC_DEFUN(PKG_CHECK_MODULES, [
  succeeded=no

  if test -z "$PKG_CONFIG"; then
    AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  fi

  if test "$PKG_CONFIG" = "no" ; then
     echo "*** The pkg-config script could not be found. Make sure it is"
     echo "*** in your path, or set the PKG_CONFIG environment variable"
     echo "*** to the full path to pkg-config."
     echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
  else
     PKG_CONFIG_MIN_VERSION=0.9.0
     if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
        AC_MSG_CHECKING(for $2)

        if $PKG_CONFIG --exists "$2" ; then
            AC_MSG_RESULT(yes)
            succeeded=yes

            AC_MSG_CHECKING($1_CFLAGS)
            $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
            AC_MSG_RESULT($$1_CFLAGS)

            AC_MSG_CHECKING($1_LIBS)
            $1_LIBS=`$PKG_CONFIG --libs "$2"`
            AC_MSG_RESULT($$1_LIBS)
        else
            $1_CFLAGS=""
            $1_LIBS=""
            ## If we have a custom action on failure, don't print errors, but 
            ## do set a variable so people can do so.
            $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
            ifelse([$4], ,echo $$1_PKG_ERRORS,)
        fi

        AC_SUBST($1_CFLAGS)
        AC_SUBST($1_LIBS)
     else
        echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
        echo "*** See http://www.freedesktop.org/software/pkgconfig"
     fi
  fi

  if test $succeeded = yes; then
     ifelse([$3], , :, [$3])
  else
     ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
  fi
])